Les formule dans calc de open office

Voici un post d’un forum bien pratique de MichelXld

Voici la source : http://user.services.openoffice.org/fr/forum/viewtopic.php?t=358

Je garde ce post très intéressant pour ne pas le perdre, un grand merci à MichelXld

Généralités
**************

Les symboles opérateurs :

Addition +
Soustraction –
Multiplication *
Division /
Exposant ^
Pourcentage %
Egal =
Différent <>
Supérieur >
Supérieur ou égal >=
Inférieur <
Inférieur ou égal <=

Texte
********

Compter le nombre de caractères contenus dans la cellule A1( chaque espace compte pour un caractère )
=NBCAR(A1)

Mettre en majuscule la première lettre de chaque mot , dans la cellule A1
=NOMPROPRE(A1)

Convertir en majuscule le texte contenu dans la cellule A1
=MAJUSCULE(A1)

Convertir en minuscule le texte contenu dans la cellule A1
=MINUSCULE(A1)

La fonction CAR renvoie le caractère ANSI spécifié ( dans l’exemple ci dessous , le résultat = 0 )
=CAR(48 )
d’autres valeurs : CAR(48 )=0 , CAR(57)=9 , CAR(65)=A , CAR(90)=Z , CAR(97)=a , CAR(122)=z

Supprimer les espaces en trop dans le texte de la cellule A1
=SUPPRESPACE(A1)

Remplacer des données dans une chaine de caracteres (exemple « 1999 » par « 2005 » )
=SUBSTITUE(« test 1999 et essai 1999 »; « 1999 »; « 2005 »)
Ne remplacer que la deuxieme occurence correspondant aux caracteres cible
=SUBSTITUE(« test 1999 et essai 1999 »; « 1999 »; « 2005 »;2)

Extraire le premier mot d’un texte saisi dans la cellule A1
=GAUCHE(A1;CHERCHE( » « ;A1;1)-1)

Afficher une lettre aléatoire entre A et Z
=CAR(ENT(ALEA()*26+1)+64)
3 autres solutions pour afficher une lettre aléatoire minuscule ou majuscule
=CHOISIR(ARRONDI(ALEA();0)+1;CAR(ENT(ALEA()*26+1)+64);CAR(ENT(ALEA()*26+1)+96))
=CAR(ENT(ALEA()*26+1)+64+CHOISIR(ARRONDI(ALEA();0)+1;0;32))
=CAR(ENT(ALEA()*26+1)+CHOISIR(ARRONDI(ALEA();0)+1;64;96))

Renvoie OUI si la cellule A1 est du texte
=SI(ESTTEXTE(A1); »OUI »; »NON »)

Compter le nombre de « a » dans la cellule A1 (Les A majuscules ne sont pas comptés)
=NBCAR(A1)-NBCAR(SUBSTITUE(A1; »a »; » »))

Compter le nombre de mots (séparés par un espace) dans la cellule A1
=NBCAR(A1)-NBCAR(SUBSTITUE(A1; » « ; » »)) + 1

Compter le nombre de cellules qui contient du texte dans la plage A1:A10
=SOMMEPROD(ESTTEXTE(A1:A10)*1)

Compter le nombre de cellules qui contient le texte XLD , uniquement quand saisi en majuscules
=SOMMEPROD((EXACT(A1:A10; »XLD »)*1))

Compter le nombre de cellules en majuscules dans la plage A1:A10
=SOMMEPROD((A1:A10<> » »)*(EXACT(A1:A10;MAJUSCULE(A1:A10))))
Remarque : les données numériques sont considérées en majuscule

Vérifier si les données sont en majuscule , minuscule , ou les deux , dans la cellule A1
=SI(EXACT(A1;MAJUSCULE(A1)); »MAJUSCULE »;SI(EXACT(A1;MINUSCULE(A1)); »MINUSCULE »; »MAJUSCULE ET MINUSCULE »))

Créer une suite logique de lettres ( de A à Z )
Tout d’abord saisissez la formule dans la cellule A1
=CAR(64+LIGNE())
ensuite utilisez la poignée de recopie vers le bas

pour obtenir une suite de lettres minuscules vous pouvez utiliser :
=MINUSCULE(CAR(64+LIGNE()))

Statistiques
**************

Compter le nombre de valeurs numériques dans la plage A1:A10
=NB(A1:A10)

Compter le nombre de cellules non vides dans la colonne A
=NBVAL(A1:A10)

Compter le nombre de cellules vides dans la plage A1:A10
=NB.VIDE(A1:A10)

Compter les cellules non vides dans une plage qui contient des formules renvoyant «  »
=SOMMEPROD((A1:A10<> » »)*1)

Compter le nombre de cellules contenant la valeur « xld » , dans la colonne A
=NB.SI(A1:A10; »xld »)

Afficher la 2eme valeur la plus élevée , de la plage A1:A10
=GRANDE.VALEUR(A1:A10;2)

Afficher la plus petite valeur de la plage A1:A10 , sans tenir compte des 0
=PETITE.VALEUR(A1:A10;NB.SI(A1:A10;0)+1)

Afficher la plus petite valeur immédiatement superieure à 0
=PETITE.VALEUR(A1:A10;NB.SI(A1:A10; »<= »&0)+1)

Afficher le classement de la cellule B1 , par rapport à la plage de valeurs B1:B10
=NB($B$1:$B$10)+1-RANG(B1;$B$1:$B$10;1)

Afficher le classement de toutes les cellules de la plage A1:A10 , les unes par rapport aux autres
(les données numériques sont dans la plage A1:A10)
=RANG(A1;DECALER($A$1;0;0;NBVAL($A$1:$A$10);1))
Saisissez le formule dans la cellule B1 et ensuite faites un « Glisser » , jusqu’à la cellule B10

Afficher la valeur numérique qui apparait le plus souvent dans la plage A1:A10
=MODE(A1:A10)

Afficher la donnée qui apparaît le plus souvent et au moins 3 fois dans la plage A1:A10
=SI(NB.SI(A1:A10;MODE(A1:A10))>2;MODE(A1:A10); » »)

Compter le nombre de valeurs identiques entre deux plages
=SOMMEPROD(NB.SI(A1:A10;B1:B10))

Compter le nombre de valeurs identiques (unique) entre deux plages
=SOMMEPROD((FREQUENCE(A1:A10;B1:B10)>0)*1)-1

Compter le nombre d’éléments qui répond à plusieurs critères sur différentes colonnes
=SOMMEPROD((A1:A10 = »Valeur1″)*(B1:B10= »Valeur2″)*(C1:C10= »Valeur3″))

Compter le nombre de données numériques différentes dans la plage A1:A10
=SOMMEPROD(1/NB.SI(A1:A10;A1:A10))

Compter le nombre de valeurs comprises entre 50 et 60 , dans la plage A1:A10
=SOMMEPROD((A1:A10 >=50)*(A1:A10 <=60))
Une autre solution
=NB.SI(A1:A10; »>= »&50)-NB.SI(A1:A10; »>= »&60)

Renvoie « oui » si le contenu de la cellule B1 apparaît dans la plage A1:A10
=SI(NB.SI(A1:A10;B1); »oui »; »non »)

Compter le nombre de lignes dont la date correspond au mois de Décembre
A1:A10 est la plage contenant les dates au format jj/mm/aaaa
12 est l’index du mois de Décembre
=SOMMEPROD((MOIS(A1:A10)=12)*1)

Compter le nombre de valeurs Impaires dans la plage de cellules B1:B20
=SOMMEPROD((MOD(B1:B20;2)=1)*1)
=SOMMEPROD(MOD(B1:B20;2)*1)
=SOMMEPROD((B1:B20=IMPAIR(B1:B20))*1)

Math et Trigo
****************

Savoir si la valeur de la cellule est paire(la formule renvoie 1) ou impaire( la formule renvoie 0)
=(A1=PAIR(A1))*1

Savoir si la valeur de la cellule est paire(la formule renvoie Vrai) ou impaire( la formule renvoie Faux)
=(A1=PAIR(A1))

SOUS.TOTAL Renvoie le sous-total d’une plage de cellules ( somme de la plage A2:A5 dans l’exemple )
=SOUS.TOTAL(9;A2:A5)

Les arguments associés à la fonction SOUS.TOTAL :
1 Moyenne
2 NB
3 NBVAL
4 MAX
5 MIN
6 PRODUIT
7 ECARTYPE
8 ECARTYPEP
9 SOMME
10 VAR
11 VAR.P

Un Sous Total peut etre affecté à plusieurs plages de cellules( moyenne des plages A2:A5 et C2:C5 dans l’exemple )
=SOUS.TOTAL(1;A2:A5;C2:C5)

Compter le nombre de X dans la plage A2:A10,si la valeur associée dans la colonne B est inférieure à 50
= SOMMEPROD((A2:A10 = « X »)*(B2:B10<50))

Additionner les valeurs de la colonne B , si la colonne A contient le mot « xld »
=SOMME.SI(A1:A10; »Xld »;B1:B10)

Renvoyer un nombre aleatoire entre 1 et 3
=ENT(ALEA()*3+1)

Insérer un exposant dans une formule( exemple exposant 2 )
=A1^2
Remarque : la fonction puissance permet d’obtenir le meme résultat
=PUISSANCE(A1;2)

Extraire la racine carré d’un nombre
=A1^(1/2)

Extraire la racine cubique d’un nombre
=A1^(1/3)

Arrondir la valeur de la cellule A1 à l’entier immédiatement inférieur
=ENT(A1)

La différence entre les fonctions TRONQUE et ENT :
Les deux fonctions renvoient des nombres entiers .
Les fonctions ENT et TRONQUE diffèrent uniquement lorsqu’il s’agit de nombres négatifs.
TRONQUE supprime la partie décimale d’un nombre ( l’exemple ci-dessous renvoie -10)
=TRONQUE(-10,5;0)
ENT arrondit les nombres à l’entier immédiatement inférieur ( l’exemple ci-dessous renvoie -11)
=ENT(-10,5)

Arrondir la valeur de la cellue A1 à 2 chiffre apres la virgule
=ARRONDI(A1;2)

Arrondit A1 à la valeur entière immédiatement supérieure
=ARRONDI.SUP(A1;0)

Arrondit A1 à la valeur supérieure comportant trois décimales
=ARRONDI.SUP(A1;3)

Arrondit A1 à gauche du séparateur décimal, à la centaine immédiatement supérieure
=ARRONDI.SUP(A1;-2)

Arrondit A1 à la valeur entière immédiatement supérieure
=ARRONDI.INF(A1;0)

Arrondit A1 à la valeur inférieure comportant trois décimales
=ARRONDI.INF(A1;3)

Arrondit A1 à gauche du séparateur décimal, à la centaine immédiatement inférieure
=ARRONDI.INF(A1;-2)

Arrondir la valeur de la cellule A1 au multiple de 5 le plus proche ( par exemple 17,6 renvoie 20 )
=ARRONDI.AU.MULTIPLE(A1;5)

Arrondir aux 5 centièmes inférieurs
=A1-MOD(A1;0,05)
=A1-MOD(A1;5%)

Calculer des montants de traite identiques en valeurs entieres , la totalité des décimales étant appliquée sur la dernière traite
La somme totale est en A1 , le nombre de traites est en B1
Le montant de chaque traite ( hormis la derniere )
=ARRONDI($A$1/$B$1;0)
Le montant de la derniere traite
=A1-(ARRONDI(A1/B1;0)*(B1-1))

Arrondir à la dizaine la plus proche ( 213,05 renvoie 210 , 216,001 renvoie 220
=ARRONDI(A1/10;0)*10

Récuprérer la partie décimale de la cellule A1 ( ne fonctionne que pour les données positives)
=A1-ENT(A1)

Compter le nombre de fois ou « OOo » dans la plage A1:A10 , est classé « number one » dans la plage B1:B10
= SOMMEPROD((A1:A10 = « OOo »)*(B1:B10= »number one »))

Calculer une moyenne sans tenir compte des zéros
=SOMME(A1:A10)/NB.SI(A1:A10; »>0″)

Afficher le résultat de la formule (A1+A2) , uniquement quand les deux cellules sont remplies
=SI(ET(A1<> » »;A2<> » »);A1+A2; » »)

Afficher le résultat de la formule (A1/B1) , uniquement si le résultat ne renvoie pas une erreur
=SI(ESTERREUR(A1/B1); » »;A1/B1)

Additionner les cellules de la plage C1:C10 , si la cellule associée dans la plage A1:A10 est égal à « xld » et si la cellule dans la plage B1:B10 est égal à 50
= SOMMEPROD((A1:A10 = « xld »)*(B1:B10=50)*(C1:C10))
Les plages de cellules pour chaque matrice doivent etre identiques .

Afficher le sinus d’une valeur définie en degrés
dans le fonction SIN(nombre) , nombre représente l’angle exprimé en radians .
il faut dont multiplier la valeur par PI()/180 ou utiliser la fonction RADIANS pour la convertir en radians
=SIN(RADIANS(30))
=SIN(30*PI()/180)

Convertir des degrés décimaux en d mn s
en A1 : La valeur degré en décimal
en B1 : =ENT(A1)
en B2 : =ENT(60*(A1-B1))
en B3 : =3600*(A1-B1-1/60*B2)
Dans la cellule finale : =B1 &  » degrés  » & B2& » minutes  » & B3 & » secondes »

Afficher la racine Niéme d’un nombre
Par exemple : si la cellule A1 contient la valeur 27 , la formule ci-dessous renvoie 3
=A1^(1/3)

Afficher la Valeur absolue d’un nombre ( nombre sans son signe )
=ABS(-10)
Cet exemple renvoie le résultat : 10

Additionner les valeurs absolues de la plage A1:A5 : ( sans tenir compte du signe des nombre )
=SOMMEPROD(ABS(A1:A5))

Retrouver le plus grand diviseur commun d’une plage de cellules
=PGCD(A1:A5)

Retrouver le plus petit multiple commun dune plage de cellules
=PPCM(A1:A5)

Renvoie une valeur arrondie au nombre entier IMPAIR le plus proche en s’éloignant de zéro
=IMPAIR(A1)

Renvoie une valeur arrondie au nombre entier PAIR le plus proche en s’éloignant de zéro
=PAIR(A1)

Scientifiques
**************

Convertit un nombre décimal compris entre -512 et 511 en nombre binaire.
=DECBIN(100;8 )
renvoie 01100100.
8 est le nombre de chiffres à utiliser.
100 est le nombre décimal. S’il s’agit d’un nombre négatif, la fonction renvoie un nombre binaire composé de 10 caractères.
Le bit maximum est le bit de signe, les 9 autres bits sont la valeur.

Tester l’égalité de deux nombres
Renvoie 1 si les arguments sont égaux , sinon renvoie 0.
=DELTA(A1;B1)

Renvoyer le nombre de combinaisons possibles , en fonction de l’argument choisi
exemple nombre de combinaisons pour former des groupes de 3 pieces sur un ensemble total de 10 pièces
=COMBIN(10;3)

Les Dates et les Heures
****************************

Généralité sur les dates dans les formules
1 = 1 jour = 24 heures

Renvoie le jour de la semaine pour une date spécifiiée dans la cellule A1 : Dimanche=1 , Samedi=7
=JOURSEM(A1)

Renvoie le jour de la semaine pour une date spécifiiée dans la cellule A1 : Lundi=1 , Dimanche=7
=JOURSEM(A1;2)

Renvoie le jour de la semaine pour une date spécifiiée dans la cellule A1 : Lundi=0 , Dimanche=6
=JOURSEM(A1;3)

Afficher le numéro du jour ( pour la date d’aujourd’hui )
=AUJOURDHUI()-DATE(ANNEE(AUJOURDHUI());1;0)

Soustraire des heures qui sont au format « 20h15″
=CNUM(SUBSTITUE(A2; »h »; »: »))-CNUM(SUBSTITUE(A1; »h »; »: »))
(Adaptez le format de la cellule conteant la formule)

Afficher le nombre de jours dans un mois , pour une date définie dans la cellule A1
=JOUR(DATE(ANNEE(A1);MOIS(A1)+1;0))

Afficher la date du jour au format texte
=TEXTE(AUJOURDHUI(); « jjjj jj mmmm aaaa »)

Calculer le temps écoulé , pour des heures saisies en A1(début) et A2(fin)
=MOD(A2-A1;1)
Les cellules A1 , A2 et celle contenant la formule doivent etre au format [hh]:mm

Extraire le nombre de journées de 8 heures , pour un total d’heures saisi dans la cellule A1 au format [hh]:mm
=ENT(A1*24/8 )
Et pour renvoyer le restant d’heures
=((A1*24/8 )-ENT(A1*24/8 ))*8

Remarque :
Utiliser le format [hh]:mm:ss pour afficher un nombre d’heures supérieur à 24 dans une cellule

Afficher Vrai si la date dans la cellule A1 est un jour de Week end , sinon renvoie Faux
=JOURSEM(A1;2)>5

Calculer l’age en tenant compte du mois et de l’année de naissance
La date est saisie dans la cellule A1
=ANNEE(AUJOURDHUI()-A1)-1900& » ans « &MOIS(AUJOURDHUI()+1-A1)-1& » mois  »

Afficher la moyenne du temps passé en mm:ss , avec en A1 le temps total en secondes et en A2 le nb d’occurrences
=A1/24/60/60/A2
La cellule contenant la formule doit etre au format [mm]:ss

Afficher le numéro de semaine pour une date saisie en A1
=ENT(MOD(ENT((A1-2)/7)+0,6;52+5/28 ))+1

Convertir des secondes saisies dans la cellule A1 en heures ( la cellule contenant la formule au format hh:mm:ss )
=A1/60/60/24
Une autre solution ( la cellule contenant la formule toujours au format hh:mm:ss )
=A1* »0:0:1″

Convertir en heure une somme de minutes
=SOMME(A1:A10)/1440
(Appliquer le format heure à la cellule de résultat )

Compter le nombre de dates correspondant au mois de Février(2) dans la plage de cellules A1:A10
=SOMMEPROD((MOIS(A1:A10) = 2)*1)

Afficher le premier Lundi du mois, pour une date saisie dans la cellule A1
=A1-JOUR(A1)+9-JOURSEM(A1-JOUR(A1))
Pensez à adapter le format de la cellule contenant la formule

Afficher le dernier jour du mois , pour une date saisie dans la cellule A1
=FIN.MOIS(DATE(TEXTE(A1; »aaaa »);TEXTE(A1; »mm »);1);0)

Une autre solution
=DATE(ANNEE(A1);MOIS(A1)+1;0)

Afficher le dernier jour du mois en cours
=FIN.MOIS(AUJOURDHUI();0)

Afficher le numero de trimestre , pour une date saisie en A1
= »TRIMESTRE « &ENT((MOIS(A1)+2)/3)

Multiplier des heures (au format hh:mm ) par un nombre
par exemple 01:30 x 2 = 3
=A1*B1*24

Ajouter 30 minutes à une heure saisie en A1
=A1+TEMPS(0;30;0)

Arrondir à l’heure la plus proche ( 2:45 devient 3:00 )
=ARRONDI(A1/(1/24);0)*(1/24)
Pensez au adapter le format des cellules

Mesurer le temps écoulé entre 2 dates au format jj.mm.aa hh:mm
A1 : heure de départ
A2 : heure d’arrivée
Ces deux cellules sont au format jj/mm/aaaa hh:mm
=ENT(A2-A1)& » j « &(HEURE(A2)<HEURE(A1))*24+HEURE(A2)-HEURE(A1)& » h »

Afficher le 3eme dimanche du mois de juin (Fêtes des Pères)
L’année est saisie en B1
=(« 22/6/ »&B1)-JOURSEM(« 1/6/ »&B1;2)

Recherches et matrices
*****************************

Renvoyer la dernière donnée saisie dans la colonne A ( ne fonctionne pas s’il y a des cellules vides )
=INDIRECT(ADRESSE(NBVAL(A1:A10000);1))

Afficher la position d’une valeur recherchée (exemple : « Xld » ) dans la plage cible A1:A10
=EQUIV(« Xld »;A1:A10;0)
Si le mot recherché est dans la cellule A3 , le résultat renvoyé sera 3
La valeur recherchée peut etre numérique ou du texte
La spécificité des recherches de texte :
La fonction EQUIV n’est pas sensible aux majuscules ou minuscules .

Insérer un lien hypertexte dans la cellule, pour ouvrir un autre document
=LIEN_HYPERTEXTE(« file:///C:/Documents and Settings/michel/monFichier.txt »; »cliquez ici! »)
Attention à bien utiliser des Slash « / » , et non des antislash « \ »

Si vous souhaitez créer un lien hypertexte vers un emplacement précis dans un document Writer,
il faut utiliser un signet pour définir cet emplacement.
L’exemple suivant crée un lien hypertexte vers le signet « monSignet » dans le document nommé monFichier.sxw
=LIEN_HYPERTEXTE(« file:///C:/Documents and Settings/michel/monFichier.sxw#monSignet »; »cliquez ici! »)

Afficher la lettre de la colonne , pour la cellule ou est placée cette formule .
=GAUCHE(ADRESSE(1;COLONNE();4);NBCAR(ADRESSE(1;COLONNE();4))-1)

Chercher la valeur « Xld » dans la colonne gauche de la plage A1:D10 , et renvoyer la valeur située dans la même ligne et dans la 4eme colonne de la plage
=RECHERCHEV(« Xld »;A1:D10;4;0)

Compter le nombre de caracteres à droite de l’Arobas « @ »
=NBCAR(A1)-TROUVE(« @ »;A1;1)

Afficher de façon aléatoire une des données se trouvant dans la plage A1:A10
=INDEX(A1:A10;ENT(ALEA()*10+1);1)

Afficher de façon aléatoire une des données contenue dans la formule
=CHOISIR(ENT(ALEA()*6+1); »Valeur1″; »Valeur2″; »Valeur3″; »Valeur4″; »Valeur5″; »Valeur6″)

Insérer une variable dans une formule
Dans l’exemple ci dessous , si la cellule B1=5 , la formule effectuera la somme de la plabe A1:A5
=SOMME(INDIRECT(« A1:A »&B1))

Récuperer une donnée sur 2 , dans la colonne A ,
pour commencer la recherche dans la 1ere ligne de la colonne A:
=DECALER($A$1;(LIGNE()-1)*2;0)
pour commencer la recherche dans 2eme ligne de la colonne A :
=DECALER($A$1;LIGNE()*2-1;0)
Dans les 2 cas , étendre les formules dans la colonne de résultat

Renvoyer le rang de la cellule A2 dans la plage A1:A10 (équivalent de la position dans la plage apres un tri )
=RANG(A2;A1:A10;0)
Ne fonctionne que pour des données numériques
Remplacer 0 par 1 pour utiliser l’ordre décroissant

Afficher une série de données dans le sens inverse
Les données de base sont dans la plage A1:A10 .Saisissez la formule dans chaque cellule de la plage B1:B10
=DECALER($A$1;10-LIGNE();0)

Retrouver les données de la plage A1:A10 qui sont aussi dans la plage B1:B10
Saisir la formule en C1 par exemple , puis l’étirer vers le bas
=SI(NB.SI($B$1:$B$10;A1)>0;A1; » »)

Informations
***************

Généralités sur la fonction CELLULE :
Renvoie des informations sur la mise en forme, la position ou le contenu de la cellule supérieure gauche d’une référence.
( voir l’aide en ligne pour plus de détails : ci-dessous quelques exemples d’utilisation )

Afficher le chemin et le nom du classeur
=CELLULE(« filename »)
Remarque : le résultat renvoie juste le nom de la feuille précédé des caractères « #$ si le classeur n’est pas enregistré

Afficher des smileys différents en fonction de la valeur de la cellule A1
( la police de caractère doit etre de type « Wingdings » , dans la cellule contenant la formule )
=SI(A1>=0; »J »; »L »)

Logique
**********

Utiliser plusieurs conditions dans la fonction Si :
Dans cet exemple , la formule renvoie « Faux » si toutes les cellules A1 ,B1 et C1 sont vides et Vrai si au moins une des cellules est non vide
=SI(ET(A1= » »;B1= » »;C1= » »); »Faux »; »Vrai »)

Vérifier si la valeur de la cellule A1 est comprise entre 10 et 20 , sinon indiquer la position en dehors de la plage cible
=SI(A1<10; »AU DESSOUS »;SI(ET(A1>=10;A1<=20); »DANS PLAGE »; »AU DESSUS »))

Renvoyer 0 si le résultat d’une formule est négatif
=SI(SOMME(A1:A10)>0;SOMME(A1:A10);0)
une autre solution
=MAX(0;SOMME(A1:A10))

Vérifier si la valeur de la cellule A1 est comprise entre 10 et 20 ( renvoie Vrai ou Faux )
=ET(A1>=10;A1<=20)

La fonction OU :
Renvoie VRAI si au moins un argument est VRAI et FAUX si tous les arguments sont FAUX
Cet exemple affiche le texte « OK » si la cellule A1=10 ou si la cellule A2=20
=SI(OU(A1=10;A2=20); »VRAI »; » »)

Divers
*********

Pour afficher les formules dans les cellules :
Menu Outils
Options
OpenOffice.orf Calc
Affichage
cochez l’option « Formules »

Il est aussi possible de précéder la formule d’une apostrophe (ou d’un espace) pour qu’elle s’affiche dans la cellule
‘=A1+A2

Insérer un commentaire dans la formule
=A1*A2+N(« mon commentaire »)

bon Week end
michel

Laisser un commentaire

Votre adresse de messagerie ne sera pas publiée. Les champs obligatoires sont indiqués avec *